28. Algoritmos || Ejercicios estructuras repetitivas Pseint

Ejercicios algoritmos Pseint

36. Hacer un algoritmo en Pseint para calcular la serie de Fibonacci.

Algoritmo Fibonacci
 definir xx, yy, zz,num,i Como Entero;
 xx<-0;
 yy<-1;
 Escribir "INGRESE UN NUMERO";
 num<-0;
 Leer num;
 PARA I<-0 HASTA num CON PASO 1 Hacer
  Escribir xx;
  zz<-yy+xx;
  xx<-yy;
  yy<-zz;
 FinPara
FinAlgoritmo

Diagrama de flujo

Diagrama Nassi-Shneiderman

37. Hacer un algoritmo en Pseint para conseguir el M.C.D de un número por medio del algoritmo de Euclides.

Algoritmo Algoritmo_Euclides
 Definir num1, num2, resto como entero;
 
 
 Escribir "Ingrese el primer número";
 Leer num1;
 Escribir "Ingrese el segundo número";
 Leer num2;
 
 Mientras (num2 <> 0) Hacer
  resto <- num2;
  num2 <- num1 % num2;
  num1 <- resto;
 FinMientras
 
 Escribir "El MCD es : ", num1;
FinAlgoritmo

Diagrama de flujo

Diagrama Nassi-Shneiderman

38. Hacer un algoritmo en Pseint que nos permita saber si un número es un número perfecto.

Algoritmo Numero_Perfecto
 // inicio de variables
 Definir num,cont,canti,suma,resto Como Entero;
 Escribir 'Ingrese un número';
 Leer num;
 cont <- 0;
 canti <- 0;
 // inicio de ciclos
 Mientras (num<>cont) Hacer
  cont <- cont+1;
  Si (cont<>num) Entonces
   resto <- num MOD cont;
   Si (resto=0) Entonces
    canti <- canti+cont;
   FinSi
  SiNo
   cont <- num;
  FinSi
 FinMientras
 Escribir 'Suma de los divisores: ',canti;
 // imprime los contadores
 Si (num=canti) Entonces
  Escribir 'Es perfecto';
 SiNo
  Escribir 'No es perfecto';
 FinSi
FinAlgoritmo

Diagrama de flujo

Diagrama Nassi-Shneiderman

39. Hacer un algoritmo en Pseint que cumpla con la aproximación del número pi con la serie de Gregory-Leibniz. La formula que se debe aplicar es:

Pi = (4/1) - (4/3) + (4/5) - (4/7) + (4/9) - (4/11) + (4/13) - (4/15) ...

Algoritmo Aproximacion_PI
 //serie Gregory-Leibniz
 //Pi = (4/1) - (4/3) + (4/5) - (4/7) + (4/9) - (4/11) + (4/13) - (4/15) ...
 Definir i, num, conta como entero;
 Definir _pi como real;
 _pi <- 0;
 conta <- 0;
 
 Escribir "Ingrese un número";
 Escribir "Para calcular la sucesión de pi";
 Leer num;
 
 para i <-1 hasta num Con Paso 2 hacer
  
  si (conta mod 2 = 0) Entonces
   _pi <- _pi + (4 / i);
  SiNo
   _pi <- _pi - (4/ i);
  FinSi
  conta <- conta + 1;
  
 FinPara
 
 Escribir "Pi se aproxima a: ", _pi;
 
FinAlgoritmo

Diagrama de flujo

Diagrama Nassi-Shneiderman

40. Hacer un algoritmo en Pseint que cumpla con la aproximación del número pi con la serie de Nilakantha. La formula que se debe aplicar es:

Pi = = 3 + 4/(2*3*4) - 4/(4*5*6) + 4/(6*7*8) - 4/(8*9*10) + 4/(10*11*12) - (4/(12*13*14) ...

Algoritmo Aproximacion_PI
 // serie Nilakantha
 // Pi = = 3 + 4/(2*3*4) - 4/(4*5*6) + 4/(6*7*8) - 4/(8*9*10) + 4/(10*11*12) - (4/(12*13*14) ...
 Definir i,num,conta Como Entero;
 Definir _pi Como Real;
 _pi <- 0;
 conta <- 0;
 Escribir 'Ingrese un número';
 Escribir 'Para calcular la sucesión de pi';
 Leer num;
 Para i<-2 Hasta num Con Paso 2 Hacer
  Si (conta MOD 2=0) Entonces
   _pi <- _pi+(4/(i*(i+1)*(i+2)));
  SiNo
   _pi <- _pi-(4/(i*(i+1)*(i+2)));
  FinSi
  conta <- conta+1;
 FinPara
 Escribir 'Pi se aproxima a: ',_pi+3;
FinAlgoritmo

Diagrama de flujo

Diagrama Nassi-Shneiderman